Automic Workload Automation

The documentation does not make the difference between processor and activator entirely clear, but I think I understand it now.

Processor: The parent task, for tasks that run inside a workflow, schedule, or job group
Activator: The effective parent for tasks started any other way, including:

• tasks started manually by a user (via the JUI or AWI)
• tasks started via the CallAPI
• tasks started via the Java Application Interface (the ExecuteObjectclass)
• tasks started via ACTIVATE_UC_OBJECT
• tasks started via object settings likeelse-execute(e.g., notification objects)
• tasks started from task properties (e.g, post-conditions)

: PRINT "ACT: &$ACTIVATOR_RUNID#"
: PRINT "PRC: &$PROCESSOR_RUNID#"
: IF &$ACTIVATOR_RUNID# = "" OR " "
:  SET &PARENT_RUNID# = &$PROCESSOR_RUNID#
: ELSE
:  SET &PARENT_RUNID# = &$ACTIVATOR_RUNID#
: ENDIF
: PRINT "&&PARENT_RUNID# = &PARENT_RUNID#"

UC4.PRINT_TASK_DETAILS.JOBI

:SET &LNR# = SYS_ACT_ME_LNR()
:IF &LNR# <> ""
:  SET &LNR# = FORMAT(&LNR#,"000")
:ELSE
:  SET &LNR# = "  "
:ENDIF
:IF &$ALIAS# <> &$NAME#
:  SET &ALIAS# = "(&$ALIAS#)"
:  SET &Header# = "              Run ID      Type  Lnr  Name (Alias)"
:ELSE
:  SET &Header# = "              Run ID      Type  Lnr  Name"
:ENDIF
:PRINT "&Header#"
:IF &$IN_PROCESSFLOW# = "Y"
:  IF &$TOP_PROCESSFLOW_RUNID# <> &$PROCESSOR_RUNID#
:    SET &TOP_PROCESSFLOW_RUNID# = FORMAT(&$TOP_PROCESSFLOW_RUNID#,"0000000000")
:      PRINT "Top WF     :  &TOP_PROCESSFLOW_RUNID#  &$PROCESSOR_TYPE#       &$TOP_PROCESSFLOW_NAME#"
:  ENDIF
:ENDIF
:IF &$PROCESSOR_RUNID# <> ""
:  SET &PROCESSOR_RUNID# = FORMAT(&$PROCESSOR_RUNID#,"0000000000")
:  PRINT "Processor  :  &PROCESSOR_RUNID#  &$PROCESSOR_TYPE#       &$PROCESSOR#"
:ENDIF
:IF &$ACTIVATOR_RUNID# <> ""
:  IF &$ACTIVATOR_RUNID# <> &$PROCESSOR_RUNID#
:    SET &ACTIVATOR_RUNID# = FORMAT(&$ACTIVATOR_RUNID#,"0000000000")
:    PRINT "Activator  :  &ACTIVATOR_RUNID#  &$ACTIVATOR_TYPE#       &$ACTIVATOR#"
:  ENDIF
:ENDIF
:SET &RUNID# = FORMAT(&$RUNID#,"0000000000")
:PRINT "This task  :  &RUNID#  &$OBJECT_TYPE#  &LNR#  &$NAME# &ALIAS#"
:IF &$PARTNER_TYPE# <> ""
:  PRINT "  Partner type : &$PARTNER_TYPE#"
:ENDIF
:IF &$IN_PROCESSFLOW# = "Y"
! Version 12.0 and later only
! :  IF &$COMPONENT_NAME# <> ""
! :    PRINT "Component name : &$COMPONENT_NAME#"
! :  ENDIF
:ENDIF
:SET &ACTIVE# = SYS_STATE_ACTIVE()
:PRINT "Task Active: &ACTIVE#"

              Run ID      Type  Lnr  Name (Alias)
Top WF     :  0132805241  JOBP       UC0.MAL.TASK_DETAILS_TEST_PARENT.JOBP
Processor  :  0132809191  JOBP       UC0.MAL.TASK_DETAILS_TEST.JOBP
This task  :  0132809192  SCRI  002  UC0.MAL.TASK_DETAILS_TEST.SCRI (CHILD_TASK)
Task Active: N


Michael Lowry said:

I do not know of a straightforward way to determine the alias or Lnr of the parent workflow within its parent.

Wolfgang Brueckler wrote:

=> INC with a prep_process_var on an SQLI VARA should do the trick....

Or an EXEC VARA & SQL job. ;)

I’m a bit confused about the meaning of this text in the documentation of superordinate tasks https://docs.automic.com/documentation/webhelp/english/AWA/12.1/DOCU/12.1/AWA%20Guides/help.htm#AWA/Executions/Exec_SuperordinateTask.htm:

Activator (ACT): This type directly activates tasks but it is not responsible for monitoring their execution:
...
Tasks that execute the SYS_STATE_ACTIVE script element
...

This suggests that merely running SYS_STATE_ACTIVE()  in a task will impact whether the activation type is PRC or ACT. My tests did not confirm this. Running SYS_STATE_ACTIVE() in a task has no effect on whether the activation type of the task is PRC or ACT

Incidentally, running SYS_STATE_ACTIVE() on the task itself (i.e., with no arguments) always returns N. I believe this is because the evaluation of AE script statements happens during activation/generation, so when the command is run, the task is not yet active. Running the command in this way does not seem particularly useful.