Automic Workload Automation

The following JOBI, UC4.RESOLVE_AGENT_GROUP.JOBI, allows one to set an agent group programmatically/dynamically.

:SET &AGENT_OR_AGENTGROUP# = "WINFT"
:INCLUDE UC4.RESOLVE_AGENT_GROUP.JOBI
:SET &ACTUAL_TARGET_AGENT# = &AGENT#

This JOBI acts like a function:

•  Input: &AGENT_OR_AGENTGROUP# — the name of anagent or an agent group.
• Output: &AGENT# —
  • If &AGENT_OR_AGENTGROUP# contains the name of anagent, then this agent name (if it is active);
  • If &AGENT_OR_AGENTGROUP# contains the name of anagent group, then the next active agent in that agent group.

I’ve encountered another quirk in the behavior of PREP_PROCESS_AGENTGROUP when the agent group has no active agents:

• Sometimes, the function creates a data sequence with an agent name and 'N' for the status.
• Other times, the function creates an empty data sequence (zero lines).

Has anyone seen this before? (v12.1.1)

I developed an improved version of the JOBI that gracefully handles the aforementioned problem with PREP_PROCESS_AGENTGROUP.

It also skips to the post-process if no active agent can be found. I made this change so that I could use this JOBI in the set of general-purpose EXEC VARAs I’m developing.

:PRINT "--- BEGIN UC4.RESOLVE_AGENT_GROUP.JOBI ---"
:ON_ERROR RESUME
:SET &AG_AGENT# = ""
:SET &PreProc_Error# = "No error"
:SET &Run_PostProc_on_Error# = &Run_PostProc_on_Error#
:SET &Stop_on_Error# = &Stop_on_Error#
:SET &Stop_Message_Num# = &Stop_Message_Num#
:IF &Stop_Message_Num# = ""
:  SET &Stop_Message_Num# = "0"
:ENDIF
:IF &AGENT_OR_AGENTGROUP# <> ""
:  SWITCH GET_OBJECT_TYPE(&AGENT_OR_AGENTGROUP#)
:  CASE 'HOSTG'
:    PRINT "&AGENT_OR_AGENTGROUP# is an agent group. Resolving it..."
:    SET &AG_HND# = PREP_PROCESS_AGENTGROUP(&AGENT_OR_AGENTGROUP#,,'BY_RULE')
:    PROCESS &AG_HND#
:      SET &AG_AGENT# = GET_PROCESS_LINE(&AG_HND#,1)
:      SET &AGENT_UP# = GET_PROCESS_LINE(&AG_HND#,2)
:      PRINT "Agent chosen by rule from agent group: &AG_AGENT#"
:      IF &AGENT_UP# = 'Y'
:        PRINT "Agent is up."
:        SET &AGENT# = &AG_AGENT#
:        TERM_PROCESS
:      ELSE
:        SET &Message# = "No active &AGENT_OR_AGENTGROUP# agent!"
:        PRINT "ERROR: &Message#"
:        SET &PreProc_Error# = "No active agent in agent group (1)"
:      ENDIF
:    ENDPROCESS
:    CLOSE_PROCESS &AG_HND#
!    Sometimes, PREP_PROCESS_AGENTGROUP returns an empty data sequence.
:    IF &AG_AGENT# = " "
:      SET &Message# = "No active &AGENT_OR_AGENTGROUP# agent!"
:      PRINT "ERROR: &Message#"
:      SET &PreProc_Error# = "No active agent in agent group (2)"
:    ENDIF
:  CASE 'HOST'
:    PRINT "&AGENT_OR_AGENTGROUP# is an agent."
:    SET &AGENT_UP# = SYS_HOST_ALIVE(&AGENT_OR_AGENTGROUP#)
:    IF &AGENT_UP#  = "Y"
:      PRINT "Agent is up."
:      SET &AGENT# = &AGENT_OR_AGENTGROUP#
:    ELSE
:      SET &Message# = "Agent &AGENT_OR_AGENTGROUP# is down!"
:      PRINT "ERROR: &Message#"
:      SET &PreProc_Error# = "Agent is down."
:    ENDIF
:  OTHER
:    PRINT "&AGENT_OR_AGENTGROUP# is not a known agent or agent group."
:    SET &Message# = "&AGENT_OR_AGENTGROUP# unknown!"
:    PRINT "ERROR: &Message#"
:    SET &PreProc_Error# = "Unknonwn agent/agent group"
:  ENDSWITCH
:ELSE
:  PRINT "No agent or agent group specified in variable &&AGENT_OR_AGENTGROUP#."
:ENDIF

! Check for agent/job type mismatch
:IF &AGENT# <> ""
:  PRINT "Object name    : &$NAME#"
:  PRINT "Object type    : &$OBJECT_TYPE#"
:  SET &OBJ_SUBTYPE# = GET_VAR(UC4.GET_OBJ_SUBTYPE.VARA_SEC_SQLI)
:  PRINT "Object subtype : &OBJ_SUBTYPE#"
:  SET &AGENT_TYPE# = GET_VAR(UC_HOST_JCL_VAR,&AGENT#)
:  PRINT "Agent name     : &AGENT#"
:  PRINT "Agent type     : &AGENT_TYPE#"
:  IF &OBJ_SUBTYPE# <> &AGENT_TYPE#
:    PRINT "Mismatch between job subtype and agent type."
:    SET &Message# = "Cannot switch to agent of different type!"
:    PRINT "ERROR: &Message#"
:    SET &PreProc_Error# = "Job/agent type mismatch"
:  ENDIF
:ENDIF
:RSET &PreProc_Error# = &PreProc_Error#

! Begin error handling
:IF &PreProc_Error# <> "No error"
:  PRINT "Error encountered in pre-process."
:  IF &Run_PostProc_on_Error# = "YES"
:    PRINT "&&Run_PostProc_on_Error# = 'YES'. Running post-process."
:    INC_SCRIPT(2)
:  ENDIF
:  IF &Stop_on_Error# = "YES"
:    PRINT "&&Stop_on_Error# = 'YES'. Stopping task with message number &Stop_Message_Num#."
:    STOP NOMSG,&Stop_Message_Num#
:  ENDIF
:ENDIF
:PRINT "--- END UC4.RESOLVE_AGENT_GROUP.JOBI ---"


More to come...

Update 2018.02.16 12:30 CET: I added handling for a non-existent agent/agent group.
Update 2018.02.16 20:10 CET: I added handling for a mismatch between the type of the job and the agent.

U00020558 Runtime error in object 'UC4.GP_SQL.JOBS(1)' line '00018': Change of platform not allowed ('<SQL>/SQL' to 'JUPITER1/UNIX' refused)

Hi Michael,

Thank you for the script.

I am also have the problem while using the GET_FILESYSTEM with the HOSTG. The GET_FILESYSTEM function supports only HOST, then I need to find the way to get the active agent from HOSTG. Finally I'm using the GET_ATT(HOSTG) and it returns the active agent for me.

Does the GET_ATT(HOSTG) is different from the script above?

Although its primary purpose is to look up an agent from an agent group, my script does do more than that. Read it to learn more.

I updated the JOBI again. The new JOBI is on my GitHub repo. Changes:

• Check agent group existence
• Check agent group mode. This isn't really used for much at the moment, other than to print a warning that only one agent will be selected for agent groups of mode all. This change adds a dependency on a new SEC_SQLI.