CA Client Automation

Anyone had any luck deploying IE 11 to their workstations via Software Delivery (SD)?

I created an msi using the IE 11 admin kit and the SD job showed successful but the PCs did not get the upgrade to IE 11.

I then used the executable and it fails with error "Exit code 40007 indicates possible error"

Any suggestions?

Thanks,

Ed

Have not tried it myself, but I found this: exit code 40007 | msi errors .com

I visited a custom yesterday who is delivering I.E 11 with Software Delivery.  Microsoft have not made it easy! In their environment they need to:

1.       Install 5 prerequisite patches

2.       Reboot

3.       Install IE 11

4.       reboot

5.       Install 4 patches

6.       Reboot

I wrote a package to do something similar.

After the IE11 install, the package installs one cumulative patch (the latest at the time of the creation). No reboot needed in between.

I install directly the IE11 exe, without customization.

Its looking like my workstations might be missing some pre-requisite KB patches.  According to this site Prerequisite updates for Internet Explorer 11 there are a bunch.  I'll let you know when I find out which one(s) are the culprit...

Thanks,

Ed

This is the list of prerequisites patches I (try to) install:

kb2639308

kb2670838

kb2729094-v2

kb2731771

kb2786081

KB2834140

KB2882822

KB2888049

Win7 SP1 is of course also needed...

So I have all of the kb prerequisites in an .msu format.  How do I create a package that will check a PC for these prerequisites and install them if needed (kinda like the CA MS rollups that I use monthly).

Thanks,

Ed

Hi

I do it in an easier way, just install the patches.

If the return code is 0 or 3010 I know the installation worked and I need a reboot before installing IE11.

Depending on the patch level of the system, maybe no patches are needed.

It usually works fine.

I can share my script if you want (vbs).

Leandro

Yes - please share vbs script.

Thanks!

Ed

The script takes two parameters:

1: Install type ("install", "installpre" (only install the prerequisites), "uninstall")

2: Logfile

This script is for 64 bit systems

You can replace "IE11-Windows6.1-kb2957689-x64.msu " with the currently latest cumulative patch.

I am not a programmer, so probably the script could be done in a nicer way. But it works...

Leandro

We have created IE 11 customize package using IEAK 11 and able to deploy on physical machine. But when are trying to deploy on VDI, it shows successfull but the machine is still on IE 8. Have to check after installing prerequisites of patches...

All the updates are installed. Still no luck.

I was finally able to work this out.  Created a Software Package that calls a batch file that installs all of the IE 11 pre-requisites.  The pre-requisites are in .msu format.  I used this article as a reference:  http://www.ca.com/us/support/ca-support-online/product-content/knowledgebase-articles/tec535980.aspx  A couple of notes on this.  First, the job always fails but the KB articles are almost always installed.  Also, the Job Output tab is NOT populated like the article states (and I did use their suggested parameters).

So I run the "Pre-requisite" job the first night and then I run IE 11 the next night.  Pretty good success rate so far.

Not clean, but it works!

Thanks all!

Ed

Are you getting correct inventory for the same. I mean for heurisitic I am getting Internet Explorer 9 bu twhen I am selecting CA Provided, it is showing IE 11.

Regards,

Mohd Wasique

As far as I can tell...  The "software inventory" on the individual computer is showing IE 11.  I also created my own software query and it shows IE 11.

Ed

We created a batch file to deploy IE11.

Some of the notes:

• Used WSUS Offline Update utility to get the IE11 x86 & x64 installer .exe from a WSUS server, utility may work to get .exe from Windows Update too.
• The above installers will install the prerequisites, but if WindowsUpdate is disabled via GPO the script will enable access.
• Deployment will work if IE is open when packaged is deployed.
• IE will not reflect new version until reboot.
• Script detects if x86 or x64 and installs proper version.
• Script will fail out of unsupported OS
• Batch file accepts /<VARIABLE>:<VALUE>
• SD package procedures set to accept 0 & 9 as success exit codes.
• Procedure set to Reboot
• Procedure set to only run on Win7 Intel or higher.

----------------

:REM Detect x86 or x64 and install appropriate IE.
:REM Detect if IE already installed.
:REM Batch file output to ITCM job status.

SETLOCAL
SET PRODUCT=Internet_Explorer_11
SET PVER=11
IF DEFINED ProgramW6432 (SET PEXE=IE11-Win7-x64-en-us.exe) ELSE (SET PEXE=IE11-Win7-x86-en-us.exe)
SET EXELOG=IE11_main.log
SET INTACT=passive
SET REBOOT=norestart
SET CLOSE=closeprograms
SET UPDATE=update-yes
SET UPDATECL=

:checkparameters
:: REM Grab the first variable supplied as a whole. Ex. /scheduledexecution:On
set SWITCHPARSE=%1
:: REM Check to see if there are no more switches, if so goto end of parsing, prevents endless loop
IF [%SWITCHPARSE%] == [] goto endswitchparsing
:: REM Reset variables as clean up.
set SWITCH=
set VALUE=
:: In the SWITCHPARSE variable, grab the two tokens separated
:: by a : and assign the first to SWITCH and the second to VALUE
for /F "tokens=1,2 delims=: " %%a IN ("%SWITCHPARSE%") DO SET SWITCH=%%a&set VALUE=%%b

:: Set switch to value (removing 1st charcter / )
SET %SWITCH:~1%=%VALUE%
SHIFT
:: REM Reset variables as clean up.
set SWITCH=
set VALUE=
goto checkparameters
:endswitchparsing

IF %UPDATE%==update-no SET UPDATECL=/update-no

ECHO Windows Version:
echo ==================
VER
IF DEFINED ProgramW6432 (ECHO x64) ELSE (ECHO x86)
echo ==================

ECHO IE Version:
echo ==================
ECHO svcVersion better indicator, but doesn't exist on all IE version.
REG QUERY "HKLM\Software\Microsoft\Internet Explorer" | FIND "Version"
echo ==================
REG QUERY "HKLM\Software\Microsoft\Internet Explorer" /v "svcVersion" | FIND " %PVER%." >NUL
IF %ERRORLEVEL%==0 ECHO %PRODUCT% Detected.  Marking as installed and quitting... & EXIT 9

:REM Unsupported OS outside of DSM requirements.
VER | FIND " 6.1.7600" >NUL
IF %ERRORLEVEL%==0 ECHO Win7-Srv2012R2 requires SP1 for this IE version.  Marking as failed and quitting... & EXIT 14
VER | FIND "6.2." >NUL
IF %ERRORLEVEL%==0 ECHO Win8-Srv2012 does NOT support this IE version.  Marking as failed and quitting... & EXIT 14
VER | FIND "6.3." >NUL
IF %ERRORLEVEL%==0 ECHO Win8.1-Srv2012R2 includes this IE version.  Marking as failed and quitting... & EXIT 14

:REM Windows update needs to be enabled so requirements and updates can be installed.
REG QUERY HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate >%TEMP%\WindowsUpdate.LOG
REG ADD HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate /v DisableWindowsUpdateAccess /d 0 /t REG_DWORD /f >NUL

ECHO Installing with command %PEXE% /%INTACT% /%CLOSE% /%REBOOT% %UPDATECL%

%PEXE% /%INTACT% /%CLOSE% /%REBOOT% %UPDATECL%
SET /A IEINSTALL.ERROR=%ERRORLEVEL%

echo ==================
IF %IEINSTALL.ERROR%==3010 ECHO 3010 - A restart is required to complete the install of %PEXE% & SET /A  IEINSTALL.ERROR=0
ECHO  %IEINSTALL.ERROR% - Install errors
echo ==================

echo Output of %WINDIR%\%EXELOG%:
echo ==================
IF EXIST "%WINDIR%\%EXELOG%" TYPE "%WINDIR%\%EXELOG%"
echo ==================

ECHO Previous Registry Values for WindowsUpdate:
echo ==================
IF EXIST %TEMP%\WindowsUpdate.LOG TYPE %TEMP%\WindowsUpdate.LOG
echo ==================
ECHO Current Registry Values for WindowsUpdate:
echo ==================
REG QUERY HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate
echo ==================

IF EXIST %TEMP%\WindowsUpdate.LOG DEL /F %TEMP%\WindowsUpdate.LOG >NUL

EXIT %IEINSTALL.ERROR%

----------------